====== String-Operationen ======


===== Leere Zeichenkette prüfen =====
 Es gibt mehrere Möglichkeiten zu prüfen, ob eine Zeichenkette leer ist. Das Problem im Skripting ist jedoch, dass Variablen keinen festen Typ haben, sondern nur Variant-Datentypen sind. Einige Vorgehensweisen können aber auch hier übernommen werden.

<code VBScript [enable_line_numbers="true"]>
  Dim sString

  sString = ""
  'Möglichkeit 1
  If sString = "" Then MsgBox "Leer"
  'Möglichkeit 2
  If StrComp(sString, "") = 0 Then MsgBox "Leer"
  'Möglichkeit 3
  If Len(sString) = 0 Then MsgBox "Leer"
  If Len(sString) > 0 Then MsgBox "Variable enthält Daten"
</code>

Die effizientes Variante ist dabei Möglichkeit 3. Hier wird kein Vergleich durchgeführt, sondern nur die Länge, die im internen Variablenkopf gespeichert ist, geprüft. Sie ist sehr schnell.
 
===== Zeichenketten vergleichen =====

Auch hier gibt es verschiedene Möglichkeiten. Hier soll nur die vielseitigste Variante dargestellt werden, die sowohl mit als auch ohne Groß-/Kleinschreibung effektiv ist.\\ 

<code VBScript [enable_line_numbers="true"]>
  Dim sText

  sText = "Vergleich"
  'Vergleich unabhängig der Groß-/Kleinschreibung
  If StrComp(sText, "vergleich", vbTextCompare) = 0 Then MsgBox "Gleich"
  'Vergleich berücksichtigt Groß-/Kleinschreibung
  If StrComp(sText, "Vergleich", vbBinaryCompare) = 0 Then MsgBox "Gleich"
</code>   

===== Zeichenketten in Zahlen umwandeln =====

Der einfachste und schnellste Weg ist das Casting, also das direkte Umwandeln einer Zeichenkette in eine Zahl mittels Operator.\\ 

<code VBScript [enable_line_numbers="true"]>
  Option Explicit

  Dim sZahl
  Dim dZahl
  Dim iZahl
  Dim lZahl

  'Achtung das Dezimalzeichen ist länderabhängig!
  'In Deutschland in es das Komma
  sZahl = "1234,23"

  If IsNumeric(sZahl) Then
      'Konvertieren nach Double
      MsgBox VarName(CDbl(sZahl))
      'Konvertieren nach Single
      MsgBox VarName(CSng(sZahl))
      'Konvertieren nach Integer
      MsgBox VarName(CInt(sZahl))
      'Konvertieren nach Long
      MsgBox VarName(CLng(sZahl))
      'Konvertieren nach Currency
      MsgBox VarName(CCur(sZahl))
  End If

  Public Function VarName(vValue)
      Select Case VarType(vValue)
          Case vbVariant Or vbArray
              If UBound(vValue, 1) > -1 Then
                  VarName = "Array: " & VarName(vValue(0))
              Else
                  VarName = "Array: Variant - Länge 0"
              End If
          Case Else
              VarName = TypeName(vValue)
      End Select
  End Function
</code>  

===== Ländercode (Gebietsschema) berücksichtigen =====

Als Dezimaltrennzeichen wird je nach Gebietsschema entweder ein Komma (z. B. Deutschland) oder ein Punkt (z. B.englischer Sprachraum, Schweiz, Lichtenstein) verwendet. Das lokale Gebietsschema kann in VBScript mit der Funktion **GetLocale** ermittelt werden (s. [[http://msdn.microsoft.com/en-us/library/0h88fahh(v=vs.85).aspx|Tabelle der Ländercodes]]).\\  Für fehlerfreie Berechnungen ist es daher ggf. erforderlich, bei Zahlenwerten, die in unter einem fremden Gebietsschema erzeugt wurde, dass Trennzeichen den Konventionen des lokalen Systems anzupassen.\\  Ein Bsp. ist die Verarbeitung von Exif-Werten, denn diese werden grundsätzlich mit einem Punkt als Trennzeichen gespeichert.\\ \\ //VBScript//\\ 

<code VBScript [enable_line_numbers="true"]>
  Wert = FF_GetExifTag("ExposureBiasValue")                   ' Wert der Belichtungskorrektur auslesen, er ist stets mit Punkt getrennt
  Gebietsschema = GetLocale                                   ' Gebietsschema des Systems ermitteln
  if Gebietsschema <> 2055 and Gebietsschema <>  5127 Then    ' nicht Schweiz oder Lichtenstein, weil dort auch der Punkt gilt
       Wert = Replace (Wert, ".", ",")                        ' Punkt durch Komma ersetzen, damit Round funktioniert
  End If
  Korrekturwert = Round(Wert, 2)                              ' jetzt wird die Round erfolgreich ausgeführt
</code>  

====== Teilstring löschen ======

<code VBScript [enable_line_numbers="true"]>
  Function DelPartString (Startstring, Delstring)
      ' löscht aus der Zeichekette 'Startstring' die Zeichenkette 'Delstring'
      ' es wird nur das erste Vorkommen von 'Delstring' berücksichtigt
      Dim i
      i = InStr (Startstring, Delstring)
      if i = 0 then Exit Function
      DelPartstring = Left (Startstring, i - 1) & Mid (Startstring, i + Len (Delstring))
  End Function
</code>   

**Alternative:**\\ 

VBScript:
<code VBScript [enable_line_numbers="true"]>
  sResult = Replace(sValue, sDelString, "", 1, 1, vbTextCompare)
</code>

JScript:
<code JavaScript [enable_line_numbers="true"]>  
  sResult = sValue.replace(sDelString,"");
</code>  
   
===== String um eine bestimmte Zeichenzahl kürzen =====

<code VBScript [enable_line_numbers="true"]>
  Function Cut(p_Str,p_Cnt)
  'schneidet vom String "p_Str" "p_Cnt" Zeichen ab

   Cut=Left(p_Str,Len(p_Str)-p_Cnt)

  End Function
</code>

===== Teilstring zwischen Begrenzern herauslösen =====

<code VBScript [enable_line_numbers="true"]>
  Function MidString (String, Suchstring1, Suchstring2)
  ' gibt den Teilstring zwischen Suchstring1 und Suchstring2 zurück
  ' Bsp.: MidString("123[456]789","[","]") ergibt "456"
      MidString = Mid(String, Instr(String,Suchstring1)+1, Instr(String,Suchstring2)-Instr(String, Suchstring1)-1)
  End Function
</code>  
siehe auch [[Pfad zerlegen]]